А там же, на https://bugzilla.mozilla.org/show_bug.cgi?id=263570, возле заголовка сообщения #67, есть ссылка https://bugzilla.mozilla.org/attachment.cgi?id=175779. Если по ней пойти, откроется какой-то непонятный текст Вот его и надо сохранить как файл с именем "firefox loader.vbs". Я на всякий случай сделал это через буфер обмена и внешний текстовый редактор. Аналогично можно поступить и с FirefoxHTML.reg, ссылка на него лежит в сообщении #66.

Люди! Если можно, объясните поподробнее, куда нужно поместить файл с именем "firefox loader.vbs", что бы открывались файлы с русскими именами.
Я так же копировал непонятный текст в блокнот, сохранил его под именем "firefox loader.vbs" и поместил в папку  C:\Program Files\Mozilla Firefox, но после этого вообще ни один файл с компа не открывается, выдает ошибку - не обнаружен сценарий firefox loader.vbs.

Оцените автоматический и оптимизированный скрипт для просмотра локальных файлов.
Windows Scripting Host должен быть установлен (в Win 9X/Me придется WSH установить самостоятельно).
'Сохранить и запустить
'Начало файла fixFireFoxLocalFiles.vbs
set WshShell = WScript.CreateObject("WScript.Shell")
Set fso = CreateObject("Scripting.FileSystemObject")

Input = InputBox("Версия FireFox","Build","1.0.1")
sFileFireFox = WshShell.RegRead("HKLM\Software\Mozilla\Mozilla Firefox " & Input & "\bin\PathToExe")
sWindows = WshShell.ExpandEnvironmentStrings("%WinDir%")
With fso
  sFolderFireFox = .GetParentFolderName(sFileFireFox) & "\"
  Set fixFile = .CreateTextFile(sFolderFireFox & "FireFoxLocalFiles.vbs", True)
End With
With fixFile
  .WriteLine("Dim WshShell")
  .WriteLine("Set WshShell = WScript.CreateObject(""WScript.Shell"")")
  .WriteLine("WshShell.Run """"""" & sFolderFireFox & "FireFox.exe"""" "" & """"""file://"" & Replace(WScript.Arguments.UnNamed(0),""\"",""/"") & """"""""")
  .Close
End With
Set fixFile = fso.CreateTextFile(sFolderFireFox & "FireFoxLocalFiles.reg", True)
With fixFile
  .WriteLine("REGEDIT4")
  .WriteLine("[HKEY_CLASSES_ROOT\FirefoxHTML\shell\open\command]")
  .WriteLine("@=""\""" & Replace(sWindows,"\","\\") & "\\System32\\WScript.exe\"" \""" & Replace(sFolderFireFox,"\","\\") & "FireFoxLocalFiles.vbs\"" / \""%1\""""")
  .Close
End With
WshShell.Run("regedit.exe """ & sFolderFireFox & "FireFoxLocalFiles.reg""")
'Конец файла fixFireFoxLocalFiles.vbs

Ты это серьезно сообщаешь или так, сдуру. Она должна обрабатываться?

Можно. Я это могу. ) А нужно? Догадайся, почему это не сделано.

Читай. Правильно мыслишь.

В скрипте много чего не исследуется, так что давайте будем запускать скрипт целенаправленно. Скрипт вылетает и в других случаях: если лис не установлен, или кто-то специально удалил ветку Mozilla's в реестре, или изменил некую системную переменную. И это не страшно, сервер сценариев выдаст сообщение об ошибке и все.

Оценил. Работает. Полезная вещь.
AK, надо бы доработать код и выложить готовый к применению файл.

'Сохранить и запустить
'Начало файла fixFireFoxLocalFiles.vbs
Option Explicit
Dim WshShell, sInput, sFileFireFox, sWindows, sFolderFireFox, fso, fixFile
Dim sMsg1, sMsg2, sMsg3, sMsg4, sName1, sName2, sName3, iFlag
On Error Resume Next

set WshShell = WScript.CreateObject("WScript.Shell")
Set fso = CreateObject("Scripting.FileSystemObject")
sName1 = "FireFoxLocalFiles.vbs"
sName2 = "FireFoxLocalFiles.old.reg"
sName3 = "FireFoxLocalFiles.reg"
sMsg1 = "Системная папка Windows не найдена"
sMsg2 = "Браузер FireFox не найден"
sMsg3 = "Не удалось создать файл "
sMsg4 = "Потребуется вручную запустить файл " & sName3 & " c правом редактирования реестра"
iFlag=0
sWindows = WshShell.ExpandEnvironmentStrings("%WinDir%")
If Not fso.FolderExists(sWindows) then sWindows = InputBox("Укажите системную папку", sMsg1,":\Windows")
If sWindows = "" Then
  WScript.Quit(0)
ElseIf Not fso.FolderExists(sWindows) Then
  MsgBox sMsg1
  WScript.Quit(1)
End If
Err.Clear
sFileFireFox = InputBox("Версия FireFox","Build","1.0.1")
if sFileFireFox="" then WScript.Quit(0)
sFileFireFox = WshShell.RegRead("HKLM\Software\Mozilla\Mozilla Firefox " & sFileFireFox & "\bin\PathToExe")
If Err.Number<>0 then
  Err.Clear
  sFileFireFox = InputBox("Укажите месторасположение браузера FireFox",sMsg2, fso.GetDriveName(sWindows) & "\Program Files\Mozilla FireFox\FireFox.exe")
End If
If sFileFireFox="" then
  WScript.Quit(0)
ElseIf Not fso.FileExists(sFileFireFox) Then
  MsgBox sMsg2
  WScript.Quit(2)
End If
With fso
  sFolderFireFox = .GetParentFolderName(sFileFireFox) & "\"
  Set fixFile = .CreateTextFile(sFolderFireFox & "FireFoxLocalFiles.vbs", True)
End With
With fixFile
  .WriteLine("Option Explicit")
  .WriteLine("Dim WshShell")
  .WriteLine("Set WshShell = WScript.CreateObject(""WScript.Shell"")")
  .WriteLine("WshShell.Run """"""" & sFolderFireFox & "FireFox.exe"""" "" & """"""file://"" & Replace(WScript.Arguments.UnNamed(0),""\"",""/"") & """"""""")
  .Close
  If Err.Number<>0 Then
    MsgBox "Невозможно сохранить файл " & sFolderFireFox & sName1
    WScript.Quit(3)
  End If
End With
'Сохраняем старое значение параметра при его наличии в reg файле
sInput = WshShell.RegRead("HKCR\FirefoxHTML\shell\open\command\")
If Err.Number=0 Then
  sInput = "@=""" & Replace(Replace(sInput,"\","\\"),"""","\""") & """"
Else
  Err.Clear
  sInput = "@=-"
End If
Set fixFile = fso.CreateTextFile(sFolderFireFox & sName2, True)
With fixFile
  .WriteLine("REGEDIT4")
  .WriteLine("")
  .WriteLine("[HKEY_CLASSES_ROOT\FirefoxHTML\shell\open\command]")
  .WriteLine(sInput)
  .Close
  If Err.Number<>0 Then
    Err.Clear
    MsgBox sMsg3 & sFolderFireFox & sName2
    iFlag = iFlag + 1
  End If
End With
'Записываем новое значение параметра
WshShell.RegWrite "HKCR\FirefoxHTML\shell\open\command\","""" & sWindows & "\System32\WScript.exe"" """ & sFolderFireFox & sName1 & """ / ""%1""","REG_EXPAND_SZ"
If Err.Number<>0 Then
  Err.Clear
  WshShell.Run("""" & sFolderFireFox & sName3 & """")
  If Err.Number<>0 Then
    Err.Clear
    MsgBox sMsg4
    iFlag = iFlag + 1
  End If
End If
'Создаем reg файл
Set fixFile = fso.CreateTextFile(sFolderFireFox & sName3, True)
With fixFile
  .WriteLine("REGEDIT4")
  .WriteLine("")
  .WriteLine("[HKEY_CLASSES_ROOT\FirefoxHTML\shell\open\command]")
  .WriteLine("@=""\""" & Replace(sWindows,"\","\\") & "\\System32\\WScript.exe\"" \""" & Replace(sFolderFireFox,"\","\\") & sName1 & "\"" / \""%1\""""")
  .Close
  If Err.Number<>0 Then
    Err.Clear
    MsgBox sMsg3 & sFolderFireFox & sName3   
    iFlag = iFlag + 1
  End If
End With
If iFlag=0 Then
  MsgBox "Готов к локальному просмотру", vbInformation, "от Лиса"
Else
  MsgBox "Могу не смочь", vbExclamation, "от Лиса"
End If
'Конец файла fixFireFoxLocalFiles.vbs

Отредактировано AK (13-03-2005 23:56:48)

АК
Проблема осталась.
Все манипуляции провожу на правах администратора, при закрытом FF.
Последовательность моих действий:
1. Копирую последний вариант скрипта в буфер обмена.
2. Вставляю в txt-файл.
3. Сохраняю его в D:/Program Files/Mozilla Firefox (там, где firefox.exe) под именем fixFireFoxLocalFiles.vbs
4. Запускаю fixFireFoxLocalFiles.vbs
5. Получаю запрос Build. Версия FireFox 1.0.1. Жму ОК.
6. Получаю сообщение от Лиса: Готово к локальному просмотру. Жму ОК.
7. Открываю FF. Ввожу в адресную строку:
file:///Dмои документы.
Папка открывается, но в адресной строке имя файла получает следующий вид:
file:///D%EC%EE%E8%20%E4%EE%EA%F3%EC%E5%ED%F2%FB.

Кстати, названия файлов на латинице у меня отображаются, например, так:
file:///D:/Program%20Files/Mozilla%20Firefox

Может в настройка конфигурации что-то изменить?

Вау! Господа! Последний скрипт работает отлично! Всё исправил при запущенном FF, причём заработало сразу, без перезапуска! А то я уж замучился всё из TComandera ручками перетаскивать

Прибольшое спасибо!

to AK
После транка с мозиллы всё работало на половину, а после внедрения твоего скрипта всё опять слетело к разбитому корыту. Нее, пошёл ставить IE умолчательным))

Я вроде бы решил для себя эту проблему, не насилуя при этом Firefox то есть, не внедряя в него никаких скриптов и плагинов. В общем, сделал простенький костыль для запуска html-файлов. У меня работает Желающие и интересующиеся могут взять вот отсюда:

http://www.alexplus.ru/x-ander/slash.zip

ЗЫ: зацените размер файла случайно получилось...

ЗЗЫ: Эх, после обновления размер изменился (был 5555)

Отредактировано X-Ander (01-04-2005 10:16:47)

Да, неприятный эффект. Я сначала не заметил - у меня это окошко само моментом закрывается, вот и не сразу увидел. Но кажется я понял куда копать. Если получится - результат выложу.

Кстати говоря, при открытии локальных файлов с русскими символами в "пути" в IE через плагин "ieview" получается примерно таже хрень...

У меня Лис 1.0.2 - с заплаткой всё работает